FM / URI

/usr/share/perl5/URI

Name	Size	Mode	Actions
file/	-	0755	rm
urn/	-	0755	rm
data.pm	3417	0644	edit dl rm
Escape.pm	7061	0644	edit dl rm
file.pm	9761	0644	edit dl rm
ftp.pm	1082	0644	edit dl rm
gopher.pm	2454	0644	edit dl rm
Heuristic.pm	6524	0644	edit dl rm
http.pm	451	0644	edit dl rm
https.pm	170	0644	edit dl rm
IRI.pm	820	0644	edit dl rm
ldap.pm	2950	0644	edit dl rm
ldapi.pm	467	0644	edit dl rm
ldaps.pm	170	0644	edit dl rm
mailto.pm	1302	0644	edit dl rm
mms.pm	151	0644	edit dl rm
news.pm	1480	0644	edit dl rm
nntp.pm	153	0644	edit dl rm
pop.pm	1233	0644	edit dl rm
QueryParam.pm	4887	0644	edit dl rm
rlogin.pm	155	0644	edit dl rm
rsync.pm	233	0644	edit dl rm
rtsp.pm	151	0644	edit dl rm
rtspu.pm	152	0644	edit dl rm
sftp.pm	124	0644	edit dl rm
sip.pm	1735	0644	edit dl rm
sips.pm	169	0644	edit dl rm
snews.pm	198	0644	edit dl rm
Split.pm	2379	0644	edit dl rm
ssh.pm	201	0644	edit dl rm
telnet.pm	154	0644	edit dl rm
tn3270.pm	154	0644	edit dl rm
URL.pm	5487	0644	edit dl rm
urn.pm	2201	0644	edit dl rm
WithBase.pm	3857	0644	edit dl rm
_foreign.pm	133	0644	edit dl rm
_generic.pm	5848	0644	edit dl rm
_idna.pm	2105	0644	edit dl rm
_ldap.pm	3275	0644	edit dl rm
_login.pm	257	0644	edit dl rm
_punycode.pm	5648	0644	edit dl rm
_query.pm	2557	0644	edit dl rm
_segment.pm	442	0644	edit dl rm
_server.pm	3750	0644	edit dl rm
_userpass.pm	1060	0644	edit dl rm

Edit: /usr/share/perl5/URI/Split.pm (2379B)

package URI::Split;

use strict;
use warnings;

our $VERSION = '1.73';
$VERSION = eval $VERSION;

use Exporter 5.57 'import';
our @EXPORT_OK = qw(uri_split uri_join);

use URI::Escape ();

sub uri_split {
     return $_[0] =~ m,(?:([^:/?#]+):)?(?://([^/?#]*))?([^?#]*)(?:\?([^#]*))?(?:#(.*))?,;
}

sub uri_join {
    my($scheme, $auth, $path, $query, $frag) = @_;
    my $uri = defined($scheme) ? "$scheme:" : "";
    $path = "" unless defined $path;
    if (defined $auth) {
	$auth =~ s,([/?\#]), URI::Escape::escape_char($1),eg;
	$uri .= "//$auth";
	$path = "/$path" if length($path) && $path !~ m,^/,;
    }
    elsif ($path =~ m,^//,) {
	$uri .= "//";  # XXX force empty auth
    }
    unless (length $uri) {
	$path =~ s,(:), URI::Escape::escape_char($1),e while $path =~ m,^[^:/?\#]+:,;
    }
    $path =~ s,([?\#]), URI::Escape::escape_char($1),eg;
    $uri .= $path;
    if (defined $query) {
	$query =~ s,(\#), URI::Escape::escape_char($1),eg;
	$uri .= "?$query";
    }
    $uri .= "#$frag" if defined $frag;
    $uri;
}

__END__

=head1 NAME

URI::Split - Parse and compose URI strings

=head1 SYNOPSIS

use URI::Split qw(uri_split uri_join);
 ($scheme, $auth, $path, $query, $frag) = uri_split($uri);
 $uri = uri_join($scheme, $auth, $path, $query, $frag);

=head1 DESCRIPTION

Provides functions to parse and compose URI
strings.  The following functions are provided:

=over

=item ($scheme, $auth, $path, $query, $frag) = uri_split($uri)

Breaks up a URI string into its component
parts.  An C<undef> value is returned for those parts that are not
present.  The $path part is always present (but can be the empty
string) and is thus never returned as C<undef>.

No sensible value is returned if this function is called in a scalar
context.

=item $uri = uri_join($scheme, $auth, $path, $query, $frag)

Puts together a URI string from its parts.
Missing parts are signaled by passing C<undef> for the corresponding
argument.

Minimal escaping is applied to parts that contain reserved chars
that would confuse a parser.  For instance, any occurrence of '?' or '#'
in $path is always escaped, as it would otherwise be parsed back
as a query or fragment.

=back

=head1 SEE ALSO

L<URI>, L<URI::Escape>

=head1 COPYRIGHT

This library is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

=cut

cmd: